Lot­to­zah­len - Anzei­ge auf einem LCD

# include "LiquidCrystal_I2C.h" 

LiquidCrystal_I2C lcd(0x27, 20, 4); 
int SENSOR = 8; 

// Array für die angekreuzten Zahlen 
int SpielZahl[6]; 

// Array für die gespielten Zahlen und die Lottozahlen 
int LottoZahl[6]; 

// Minimum/Maximum der Zufallszahlen 
int Minimum = 1; 
int Maximum = 49; 

// Anzahl der zu ziehenden Zahlen 
int Anzahl = 6; 
int SensorLesen; 

void setup()
{
  pinMode(SENSOR, INPUT);

  // bei Verwendung eines Tasters:
  // pinMode(SENSOR, INPUT_PULLUP);

  // Zufallsgenerator starten
  randomSeed(analogRead(A0));

  // LCD einschalten
  lcd.init();
  lcd.backlight();
}

int Ziehung() 
{  
  for (int i = 0; i < Anzahl; i ++)   
  {   
    /*  
      die Lottozahl gilt solange als bereits gezogen    
      bis in der for-Schleife nachgewiesen wird, dass sie neu ist         
      und BereitsGezogen den Wert false hat   
    */ 
    bool BereitsGezogen = true;    
    while (BereitsGezogen)   
    {    
      // Zahl ziehen    
      LottoZahl[i] = random(Minimum, Maximum);  
      BereitsGezogen = false;       
      /*      
        Zufallszahl mit den bereits gezogenen Zahlen vergleichen          
        i wird in der ersten for-Schleife hochgezählt  
        alle bisherigen Zahlen (ii) werden mit den bisher gezogenen Zahlen         
        (außer der gerade gezogenen) Zahlen verglichen (ii < i)         
        ist sie identisch, erhält BereitsGezogen den Wert true 
        es wird erneut eine Zufallszahl bestimmt  
        wenn die Zahl neu ist, (BereitsGezogen hat noch den Wert false)   
        wird die while-Schleife verlassen und die nächste Zahl   
        gezogen  
      */ 
      for (int ii = 0; ii < i; ii ++)   
      {
         if (LottoZahl[i] == LottoZahl[ii]) BereitsGezogen = true;       
      }
    }
  }
  /*
     das Array mit den Zahlen wird an das Hauptprogramm zurückgegeben 
     beim ersten Aufruf sind es die gespielten Zahlen
     beim zweiten Aufruf die gezogenen Lottozahlen
  */
   return LottoZahl[Anzahl];
 }

void ZahlenSortieren(int Zahlen[], int Groesse)
{
  // unsortierten Bereich des Arrays durchlaufen
  for (int i = 0; i < (Groesse - 1); i++) 
  { 
    // bei jedem Durchlauf wird das jeweils letzte Element weggelassen 
    for (int ii = 0; ii < (Groesse - (i + 1)); ii++) 
    {
      /* 
        wenn die aktuelle Zahl größer als die nachfolgende Zahl ist   
        -> aktuelle Zahl temporär speichern
        -> Zahlen vertauschen
        -> temporäre Zahl der nachfolgenden Zahl zuweisen
      */
      if (Zahlen[ii] > Zahlen[ii + 1])
      {
        int zwischengespeicherteZahl = Zahlen[ii];
        Zahlen[ii] = Zahlen[ii + 1];
        Zahlen[ii + 1] = zwischengespeicherteZahl;
      }
    }
  }
}

void loop()
{
  String GespielteZahlen = "";
  String GezogeneZahlen = "";
  String AnzahlTreffer = "";
  int Treffer = 0;

  SensorLesen = digitalRead(SENSOR);

  // bei Verwendung eines Tasters:
  // if (SensorLesen == LOW)
  if (SensorLesen == HIGH)
  {
    delay(200);

    // Ziehung der "angekreuzten" Zahlen
    Ziehung();

    ZahlenSortieren(LottoZahl, 6);
    for (int i = 0; i < Anzahl; i ++)
    {
      GespielteZahlen = GespielteZahlen + LottoZahl[i] + " ";      
      /*
        für den späteren Vergleich wird
        dem Array SpielZahl (die „gespielten“ Zahlen)   
        das identische Element des Arrays LottoZahl zugewiesen
      */ 
      SpielZahl[i] = LottoZahl[i];
    }

    // Ziehung der Lottozahlen
    Ziehung();
    ZahlenSortieren(LottoZahl, 6);

    // Vergleichen der Elemente der Arrays SpielZahl und LottoZahl
    for (int i = 0; i < Anzahl; i++) 
    { 
      for (int ii = 0; ii < Anzahl; ii++) 
      {
        // Übereinstimmung gefunden -> Treffer um 1 erhöhen
        // AnzahlTreffer: String für übereinstimmende Zahlen erzeugen
        if (SpielZahl[i] == LottoZahl[ii])
        {
          AnzahlTreffer = AnzahlTreffer + SpielZahl[i] + " ";
          Treffer ++;
        }
      }
    }

    // String GezogeneZahlen aus den Elementen des Arrays LottoZahl
    // zusammensetzen
    for (int i = 0; i < Anzahl; i++)
    {
      GezogeneZahlen = GezogeneZahlen + LottoZahl[i] + " ";
    }

    // Anzeige LCD
    lcd.clear();
    lcd.setCursor(0, 0);
    lcd.noCursor();
    lcd.print("Lottozahlen");
    lcd.setCursor(0, 1);
    lcd.print(GespielteZahlen);

    // Anzeige LCD lcd.setCursor(0, 2);
    lcd.print(GezogeneZahlen);
    lcd.setCursor(0, 3); 

    // keine Treffer 
    if (Treffer == 0) lcd.print("keine Treffer!");
    
    // getroffene Zahlen anzeigen
    else lcd.print("Treffer: " + AnzahlTreffer);
  }
}