DHT22 - Wet­ter­da­ten aufzeichnen

Das Pro­gramm soll die Wet­ter­da­ten im Seri­el­len Moni­tor anzei­gen und gleich­zei­tig auf einer SD-Kar­te im CSV-For­mat auf­zeich­nen.
Die­se Datei kann dann von einer Tabel­len­kal­ku­la­ti­on geöff­net werden.

So soll es aussehen:

Benö­tig­te Bauteile:

• RTC-Modul DS3231
• Tem­pe­ra­tur-/Feuch­tig­keits­sen­sor DHT22
• SD-Kar­ten-Modul
• Lei­tungs­dräh­te

Wenn du ein ➨Ether­net-Shield hast, kannst du das Pro­gramm ohne Ände­rung mit dem dort ver­bau­ten SD-Kar­ten-Modul ver­wen­den.
Mit einem ➨Daten­log­ger-Shield musst du den Wert für den Daten­pin auf 10 setzen.

Der Sen­sor DHT22 misst die Tem­pe­ra­tur und die Luft­feuch­tig­keit. Das hier ver­wen­de­te Bau­teil besitzt drei Anschlüs­se.
Die Ver­si­on mit vier Pins muss in der Rei­hen­fol­ge 5V → Daten (Pin) → leer → GND geschal­tet werden.

Die Ver­si­on mit vier Pins muss in der Rei­hen­fol­ge 5V → Daten (Pin) → leer → GND geschal­tet werden.

Beach­te die Pin­be­le­gung!
Die SD-Kar­te muss mit FAT32 for­ma­tiert sein!

➨ RTC-Modul

➨ SD-Kar­ten-Modul

Baue die Schal­tung auf.
(Fah­re mit der Maus über das Bild, um die Bezeich­nun­gen der Bau­tei­le zu sehen)

Je grö­ßer die Pro­gram­me wer­den, je mehr Varia­ble ver­wen­det wer­den, des­to grö­ßer ist der Spei­cher­be­darf im RAM. Über­steigt er die Gren­ze von 75%, wird eine War­nung ausgegeben.

Der phy­si­sche Spei­cher kann nicht ver­grö­ßert wer­den, es gib aber Stra­te­gien, den Spei­cher­be­darf des Pro­gramms zu ver­rin­gern. Eine soll hier vor­ge­stellt werden.

Der Ardui­no UNO ver­fügt über drei Speicherplätze:

➨Spei­cher­aus­stat­tung ver­schie­de­ner Arduinos

In den meis­ten Pro­gram­men wer­den print-Anwei­sun­gen aus­ge­führt. Jede die­ser Anwei­sun­gen belegt Spei­cher­platz im Pro­gramm­spei­cher. Da es sich aber nicht um Varia­ble han­delt, ist die dau­er­haf­te Spei­che­rung nicht notwendig.

Das ➨ F-Makro sorgt dafür, dass der Text nicht im Pro­gramm­spei­cher ver­bleibt, er wird viel­mehr im SRAM abge­legt und stellt so Spei­cher­platz im Pro­gramm­spei­cher zur Verfügung.

Bei­spie­le:

Serial.println(F("Initialisierung abgeschlossen")); 
Serial.println(F("Schreibe Messdaten in die Datei Messung.csv: ")); 
Serial.println(F("-----------------------------------"));

Sketch → Biblio­thek ein­bin­den → Biblio­the­ken verwalten

Im Kopf des Pro­gramms wer­den die benö­tig­ten Biblio­the­ken ein­ge­bun­den und die Varia­blen defi­niert.
Beach­te die Kommentare:

// Bibliothek für die SD-Karte 
# include <SdFat.h> 

// Bezeichnung der SD-Karte 
SdFat SD; 

// Bibliothek für den DHT22 
# include <SimpleDHT.h> 

// Bibliothek für das RTC-Modul 
# include <RTClib.h> 
RTC_DS3231 rtc; 

// Bezeichnung der Textdatei 
File Temperaturmessung; 

// Datenpin für das SD-Kartenmodul 
int DatenPin = 4; 
int SENSOR_DHT22 = 7; 

// Namen des Sensors (dht22) 
SimpleDHT22 dht22(SENSOR_DHT22); 
int SensorLesen; 

// Trennzeichen für die CSV-Datei 
const String TrennZeichen = ";"; 
String AktuellesDatum; 
String AktuelleZeit; 

Der set­up-Teil initia­li­siert die SD-Kar­te, star­tet das RTC-Modul und legt den pin­Mo­de für den Sen­sor fest.

void setup() 
{ 
  pinMode(SENSOR_DHT22, INPUT); 
  Serial.begin(9600); 

  // auf serielle Verbindung warten
  while (!Serial) {;}

  Serial.println(F("Initialisiere SD-Karte")); 
  if (!SD.begin(DatenPin)) 
  {  
    Serial.println(F("Initialisierung fehlgeschlagen!")); 
  } 
  else Serial.println(F("Initialisierung abgeschlossen"));
  rtc.begin(); 

  /*  
    wenn Datum und Zeit nicht korrekt → Datum/Zeit setzen
    Jahr, Monat, Tag, Stunde, Minute, Sekunde
    rtc.adjust(DateTime(2020, 10, 25, 17, 28, 30)); 
  */
}

Der loop-Teil. Beach­te die Kommentare.

void loop() 
{ 
  DateTime aktuell = rtc.now(); 
  float Temperatur; 
  float Luftfeuchtigkeit;  

  // Daten lesen 
  dht22.read2(&Temperatur, &Luftfeuchtigkeit, NULL);   

  // Funktion aufrufen 
  ZeitAusgeben(aktuell);  

  // in Strings umwandeln, . durch , ersetzen  
  String AnzeigeTemperatur = String(Temperatur);
  AnzeigeTemperatur.replace(".", ","); 
  String AnzeigeLuftfeuchtigkeit = String(Luftfeuchtigkeit);
  AnzeigeLuftfeuchtigkeit.replace(".", ",");
  Serial.print(F("Temperatur:\t\t"));
  Serial.println(AnzeigeTemperatur); 
  Serial.print(F("Luftfeuchtigkeit in %:\t")); 
  Serial.println(AnzeigeLuftfeuchtigkeit); 

  /*  
    Datei zum Schreíben (FILE_WRITE) öffnen   
    wenn sie noch nicht existiert, wird sie erstellt 
    wenn Schreiben nicht möglich → Fehlermeldung 
  */ 
  if (!Temperaturmessung.open("Messung.csv", FILE_WRITE)) 
  { 	
    Serial.print(F("Datei kann nicht ge\u00f6ffnet werden!")); 
  } 

  // wenn die Datei geöffnet werden konnte ... 
  if (Temperaturmessung)  
  {  
    Serial.println(F("Schreibe Messdaten in die Datei Messung.csv ... "));  
    Serial.println(F("-----------------------------------")); 

    // Überschrift in Datei schreiben 
    // Funktion aufrufen
    schreibeUeberschrift(); 
    Temperaturmessung.print(AktuellesDatum + TrennZeichen); 
    Temperaturmessung.print(AktuelleZeit + TrennZeichen); 
    Temperaturmessung.print(AnzeigeTemperatur + TrennZeichen); 
    Temperaturmessung.print(AnzeigeLuftfeuchtigkeit); 
    Temperaturmessung.println(); 

    // Schreibfehler abfragen  
    if (!Temperaturmessung.sync() || Temperaturmessung.getWriteError()) 
    {   
      Serial.print(F("Schreibfehler!"));  
    } 
    else    
    {  
      // Datei schließen  
      Temperaturmessung.close(); 
      Serial.println(F("Abgeschlossen.")); 
      Serial.println();  
    } 
  } 

  // Zeit bis zur nächsten Messung (eine Minute)
  delay(60000); 
}

Im loop-Teil wer­den zwei Funk­tio­nen aufgerufen:

void ZeitAusgeben(DateTime aktuell)
{
  char Datum[] = "DD.MM.YYYY";
  AktuellesDatum = aktuell.toString(Datum);

  char Zeit[] = "Uhrzeit: hh:mm:ss";
  AktuelleZeit = aktuell.toString(Zeit);
  Serial.println(AktuellesDatum + " " + AktuelleZeit);
}

void schreibeUeberschrift() 
{ 
  Temperaturmessung.println();
  Temperaturmessung.print(F("Datum")); 

  // Trennzeichen für die CSV-Datei
  Temperaturmessung.print(TrennZeichen); 
  Temperaturmessung.print(F("Zeit")); 
  Temperaturmessung.print(TrennZeichen); 
  Temperaturmessung.print(F("Temperatur in °C")); 
  Temperaturmessung.print(TrennZeichen); 
  Temperaturmessung.print(F("Luftfeuchtigkeit in %")); 
  Temperaturmessung.println(); 
}

Ver­wand­te Aufgaben:

• DHT22 - Durch­schnitts­tem­pe­ra­tur berech­nen und auf einem OLED-Dis­­play anzeigen
• DHT22 - Wet­ter­da­ten aufzeichnen
• DHT22 - Wet­ter­da­ten mit Blue­­tooth-Modul übermitteln
• DHT22 - Wet­ter­sta­ti­on LAN
• DHT22 - Wet­ter­sta­ti­on Anzei­ge auf einem LCD
• DHT22 - Wet­ter­sta­ti­on WiFi
• BMP280 - Tem­pe­ra­tur und Luft­druck messen
• TMP36 - Tem­pe­ra­tur messen
• DHT22 - Wet­ter­sta­ti­on LAN Daten speichern

Letzte Aktualisierung: 8. Mrz 2023 @ 12:38