Lot­to­zah­len - Anzei­ge auf einem OLED-Display

Lese­zeit: 6 Minu­ten

Lösung
Seite als PDF

Der Ardui­no „spielt“ für dich 6 Zah­len. Anschlie­ßend wer­den die Lot­to­zah­len gezo­gen, auf­stei­gend sor­tiert und auf die Anzahl der über­ein­stim­men­den Zah­len unter­sucht. Das Ergeb­nis wird auf einem OLED-Dis­play angezeigt.

So sieht es aus: OLED 128×64

So sieht es aus: OLED 128×32

OLED-Display

OLED-Dis­plays (Orga­nic Light Emit­ting Diode) benö­ti­gen im Unter­schied zu LCDs kei­ne Hin­ter­grund­be­leuch­tung, sie leuch­ten selbst. Eine OLED besteht aus zwei Elek­tro­den, von denen min­des­tens eine trans­pa­rent sein muss. Im Zwi­schen­raum befin­den sich orga­ni­sche Halb­lei­ter­schich­ten aus natür­li­chen Farb­stof­fen. Die orga­ni­schen Schich­ten leuch­ten, wenn sie von Gleich­strom durch­flos­sen wer­den. Basis der Tech­nik ist die Ent­de­ckung der Elek­tro­lu­mi­nes­zenz: ein Fest­kör­per wird durch Anle­gen einer elek­tri­schen Span­nung dazu ange­regt Licht zu erzeugen.

Die für den Ardui­no gebräuch­lichs­ten Bau­for­men haben eine Grö­ße von 0,96 Zoll und 1,3 Zoll. 

Sie unter­schei­den sich im ver­wen­de­ten Chip­satz:
0,96 Zoll: SSD1306
1,3 Zoll: SH1106

Benö­tig­te Bauteile:

  • Berüh­rungs­sen­sor
  • OLED-Dis­play 0,96 Zoll
  • Lei­tungs­dräh­te

Baue die Schal­tung auf.
(Fah­re mit der Maus über das Bild, um die Bezeich­nun­gen der Bau­tei­le zu sehen

Statt A4 (SDA) und A5 (SCL) kannst du auch die mit SCL und SDA beschrif­te­ten Pins verwenden.

Der Chip­satz des ver­wen­de­ten Dis­plays ist ein SSD1306 mit I2C.
Für die Ansteue­rung des OLEDs steht eine Viel­zahl von Biblio­the­ken zur Verfügung. 

Ver­wen­de­te Biblio­thek SSD1306Ascii:

... instal­liert werden.

Bin­de die benö­tig­ten Biblio­the­ken ein und defi­nie­re die Variablen:

# include "SSD1306Ascii.h"
# include "SSD1306AsciiWire.h"

// mögliche Adressen I2C: 0X3C+SA0  0x3C or 0x3D
# define I2C_ADDRESS 0x3C

// Name des OLED festlegen
SSD1306AsciiWire oled;

// Minimum/Maximum der Lottozahlen
const byte Minimum = 1;
const byte Maximum = 49;

// Berührungssensor Pin 7
byte SENSOR = 7;

// Anzahl der zu ziehenden Zahlen
const byte Anzahl = 6;

// Array für die gezogenen Zahlen
int LottoZahl[Anzahl];

Der set­up-Teil:

void setup()
{
  Serial.begin(9600);

  pinMode(SENSOR, INPUT);

  // Zufallsgenerator starten
  randomSeed(0);

  // OLED starten
  Wire.begin();
  Wire.setClock(400000L);
  oled.begin(&Adafruit128x64, I2C_ADDRESS);

  // Schriftart bestimmen
  oled.setFont(font5x7);

  oled.println("Lottozahlen");
}
Download

Ver­wen­de für Bestim­mung der Spiel­zah­len und die Zie­hung der Lot­to­zah­len die Funk­ti­on Ziehung:

int Ziehung() 
{
  for (byte i = 0; i < Anzahl; i++)
  {
    /*
      die Lottozahl gilt solange als bereits gezogen
      bis in der for-Schleife nachgewiesen wird, dass sie neu ist
      BereitsGezogen den Wert false hat
    */
    bool BereitsGezogen = true;

    while (BereitsGezogen)
    {
      // Zahl ziehen
      LottoZahl[i] = random(Minimum, Maximum);
      BereitsGezogen = false;
      /*
        Zufallszahl mit den bereits gezogenen Zahlen vergleichen
        i wird in der ersten for-Schleife hochgezählt
        alle bisherigen Zahlen (ii) werden mit den bisher gezogenen
        verglichen (ii < i)
        ist sie identisch, erhält BereitsGezogen den Wert true
        es wird erneut eine Zufallszahl bestimmt
        wenn die Zahl neu ist, (BereitsGezogen hat noch den Wert false)
        wird die while-Schleife verlassen und die nächste Zahl gezogen
      */

      for (byte ii = 0; ii < i; ii++) 
      {
        if (LottoZahl[i] == LottoZahl[ii])
          BereitsGezogen = true;
      }
    }
  }
  return LottoZahl[Anzahl];
}

Die Lot­to­zah­len wer­den mit der Funk­ti­on Zah­len­Sor­tie­ren() auf­stei­gend sortiert

void ZahlenSortieren(int Zahlen[], int Groesse) 
{
  // unsortierten Bereich des Arrays durchlaufen
  for (int i = 0; i < (Groesse - 1); i++) 
  {
    // bei jedem Durchlauf wird das jeweils letzte Element weggelassen
    for (int ii = 0; ii < (Groesse - (i + 1)); ii++) 
    {
      /*
        wenn die aktuelle Zahl größer als die nachfolgende Zahl ist
        -> aktuelle Zahl temporär speichern
        -> Zahlen vertauschen
        -> temporäre Zahl der nachfolgenden Zahl zuweisen
      */
      if (Zahlen[ii] > Zahlen[ii + 1]) 
      {
        int zwischengespeicherteZahl = Zahlen[ii];
        Zahlen[ii] = Zahlen[ii + 1];
        Zahlen[ii + 1] = zwischengespeicherteZahl;
      }
    }
  }
}

Der loop-Teil. Beach­te die Kommentare.

void loop()
{
  // Array für die gespielten Zahlen
  byte SpielZahl[6];

  // Strings und Trefferzahl definieren
  String GespielteZahlen = "";
  String GezogeneZahlen  = "";
  byte Treffer = 0;
  
  byte SensorLesen = digitalRead(SENSOR);

  if (SensorLesen == HIGH)
  {
    delay(200);

    // Ziehung der "angekreuzten" Zahlen
    Ziehung();

    // Zahlen sortieren
    ZahlenSortieren(LottoZahl, 6);


    // String GespielteZahlen aus den Elementen des Arrays LottoZahl
    // zusammensetzen
    for (byte i = 0; i < Anzahl; i++)
    {
      GespielteZahlen = GespielteZahlen + LottoZahl[i] + " ";
      SpielZahl[i] = LottoZahl[i];
    }

    // Ausgabe OLED
    oled.clear();
    oled.println("Gespielte Zahlen");
    oled.println(GespielteZahlen);
    oled.println("---------------------------------");

    // Ziehung der Lottozahlen
    Ziehung();

    // Zahlen sortieren
    ZahlenSortieren(LottoZahl, 6);


    // Vergleichen der Elemente der Arrays SpielZahl und LottoZahl
    for (byte i = 0; i < Anzahl; i++)
    {
      for (byte ii = 0; ii < Anzahl; ii++)
      {
        // Übereinstimmung gefunden -> Treffer um 1 erhöhen
        if (SpielZahl[i] == LottoZahl[ii]) Treffer ++;
      }
    }

    // String GezogeneZahlen aus den Elementen 
    // des Arrays LottoZahl zusammensetzen
    for (byte i = 0; i < Anzahl; i++)
    {
      GezogeneZahlen = GezogeneZahlen + LottoZahl[i] + " ";
    }

    // Anzeige OLED
    oled.println("Gezogene Zahlen");
    oled.println(GezogeneZahlen);
    oled.println("-----------------------------");
  
    if (Treffer == 0) oled.print("keine Treffer");
    else
    {
      oled.print(Treffer);
      oled.print(" Treffer");
    }
  }
}
Download

Lot­to­zah­len mit OLED 128×32

Download

Lot­to­zah­len mit der Biblio­thek ubg2


Startseite
Aufgaben A-Z
Suchen
Downloads
Fehlermeldungen
Seite als PDF

Ver­wand­te Aufgaben:


Letzte Aktualisierung: 1. Jan 2024 @ 19:30