Länder-Info - Programmieren mit Arduino

Lesezeit: 6 Minuten

Das Programm soll nach einem Druck auf eine der Tasten des Tastenfelds Informationen zu verschiedenen Ländern im Seriellen Monitor oder auf einem LCD anzeigen.

So sieht es im Seriellen Monitor aus:

Länder-Info Serieller Monitor

So sieht es auf dem LCD aus:

Schließe das LCD an:

➨LCD

➨Serieller Monitor

Normalerweise wäre eine komplexe Verkabelung zum Betrieb eines LCDs nötig. Der ➨I2C-Bus regelt über einen eigenen Mikroprozessor die Kommunikation der Datenleitungen untereinander. Es werden deshalb nur vier Anschlüsse benötigt.

Die Helligkeit kann mit einem Potentiometer auf der Rückseite des LCDs eingestellt werden.

Bei Programmen, die einen Taster verwenden, taucht immer das Problem auf, dass ein längerer Druck auf den Taster die gewünschte Aktion mehrfach ausführt. Selbst ein kurzes delay() kann das Problem nicht lösen, sondern höchstens abmildern. Dieses Phänomen wird „Prellen“ genannt.

Das kleine Beispielprogramm verdeutlicht das Problem:

void setup()
{
  pinMode(5, INPUT_PULLUP);
  Serial.begin(9600);

  // auf serielle Verbindung warten
  while (!Serial);
}

void loop()
{
  int TasterStatus = digitalRead(5);
  if (TasterStatus == LOW) 
  {
    delay(200);
    Serial.println("Taster gedrueckt!");
  }
}

Ein längerer Druck auf den Taster produziert die mehrfache Ausgabe des Textes.

Die Bibliothek Bounce2 löst genau dieses Problem:

Benötigte Bibliotheken:

oder: Sketch -> Bibliothek einbinden -> Bibliotheken verwalten

Benötigte Bauteile:

LCD 1602
Tastenfeld 1×4
Leitungsdrähte

Baue die Schaltung auf.
(Fahre mit der Maus über das Bild, um die Bezeichnungen der Bauteile zu sehen)

Mit einem kleinem Programm kannst du testen, ob das Tastenfeld richtig angeschlossen ist.
Die gedrückte Taste wird im ➨Seriellen Monitor angezeigt.

/*
  Anschlüsse am Tastenfeld von links nach rechts
  GND D4 D5 D6 D7
*/
int TASTER_EINS = 5;  // Taste 1 
int TASTER_ZWEI = 4;  // Taste 2 
int TASTER_DREI = 7;  // Taste 3 
int TASTER_VIER = 6;  // Taste 4 

void setup() 
{ 
  Serial.begin(9600);   

  // auf serielle Verbindung warten
  while (!Serial);
 
  // INPUT_PULLUP -> Eingangspegel auf HIGH setzen 
  pinMode(TASTER_EINS, INPUT_PULLUP); 
  pinMode(TASTER_ZWEI, INPUT_PULLUP); 
  pinMode(TASTER_DREI, INPUT_PULLUP); 
  pinMode(TASTER_VIER, INPUT_PULLUP); 
} 

void loop() 
{ 
  if (digitalRead(TASTER_EINS) == LOW) 
  {   
    delay(100); 
    Serial.println("Taste 1 an Pin " + String(TASTER_EINS));        
  } 
  if (digitalRead(TASTER_ZWEI) == LOW)          
  {  
    delay(100);   
    Serial.println("Taste 2 an Pin " + String(TASTER_ZWEI));     
  } 
  if (digitalRead(TASTER_DREI) == LOW)  
  {  
    delay(100); 
    Serial.println("Taste 3 an Pin " + String(TASTER_DREI));    
  } 
  if (digitalRead(TASTER_VIER) == LOW)   
  {  
    delay(100);  
    Serial.println("Taste 4 an Pin " + String(TASTER_VIER));    
  } 
}

Binde die benötigen Bibliotheken ein, definiere die ➨struct, die Taster und die Zuordnung der Tasten zur Bibliothek Bounce2.

# include "Bounce2.h"
# include "LiquidCrystal_I2C.h"

LiquidCrystal_I2C lcd(0x27, 20, 4);

// Vorlage
struct Laenderdaten
{
  String Name;
  float Einwohner;
  long Groesse;
  String Hauptstadt;
};

Laenderdaten Deutschland =
{
  "Deutschland",
  83.01,
  357578,
  "Berlin"
};

Laenderdaten Frankreich =
{
  "Frankreich",
  66.99,
  543965,
  "Paris"
};

Laenderdaten Belgien =
{
  "Belgien",
  11.37,
  30688,
  "Br\365ssel"
};

Laenderdaten Niederlande =
{
  "Niederlande",
  17.29,
  41543,
  "Amsterdam"
};

/*
  Anschlüsse von links nach rechts
  GND D4 D5 D7 D6
*/
int TASTER1 = 5;  // Taste 1
int TASTER2 = 4;  // Taste 2
int TASTER3 = 7;  // Taste 3
int TASTER4 = 6;  // Taste 4

// Bibliothek Bounce2
// "Prellverhinderer" für die Tasten starten
Bounce Land1 = Bounce();
Bounce Land2 = Bounce();
Bounce Land3 = Bounce();
Bounce Land4 = Bounce();

Im setup-Teil werden die Instanzen der Taster zugeordnet, das LCD-Display gestartet und der Vorwiderstand der Taster aktiviert.

void setup()
{
  // Instanzen des Objekts Bounce für jede Taste zuordnen
  // Zeitintervall einstellen
  Land1.attach(TASTER1);
  Land1.interval(20);
  Land2.attach(TASTER2);
  Land2.interval(20);
  Land3.attach(TASTER3);
  Land3.interval(20);
  Land4.attach(TASTER4);
  Land4.interval(20);

  // Eingangspegel auf HIGH setzen
  pinMode(TASTER1, INPUT_PULLUP);
  pinMode(TASTER2, INPUT_PULLUP);
  pinMode(TASTER3, INPUT_PULLUP);
  pinMode(TASTER4, INPUT_PULLUP);

  // LCD starten
  lcd.init();
  lcd.backlight();

  // Info über den Programmablauf
  lcd.setCursor(0, 0);
  lcd.print("1 = Deutschland");
  lcd.setCursor(0, 1);
  lcd.print("2 = Frankreich");
  lcd.setCursor(0, 2);
  lcd.print("3 = Belgien");
  lcd.setCursor(0, 3);
  lcd.print("4 = Niederlande");
}

Der loop-Teil:

void loop()
{
  // Taste 1 gedrückt
  if (Land1.update())
  {
    if (Land1.read() == LOW)
    {
      ZeigeDaten(Deutschland);
    }
  }
  // Taste 2 gedrückt
  if (Land2.update())
  {
    if (Land2.read() == LOW)
    {
      ZeigeDaten(Frankreich);
    }
  }

  // Taste 3 gedrückt
  if (Land3.update())
  {
    if (Land3.read() == LOW)
    {
      ZeigeDaten(Belgien);
    }
  }

  // Taste 4 gedrückt
  if (Land4.update())
  {
    if (Land4.read() == LOW)
    {
      ZeigeDaten(Niederlande);
    }
  }
}

Der Funktion ZeigeDaten wird die Struktur Laenderdaten übergeben, die Variable Land enthält das Element, das im Aufruf der Funktion ZeigeDaten übergeben wurde.

void ZeigeDaten(struct Laenderdaten Land)
{
  lcd.clear();
  lcd.setCursor(0, 0);
  lcd.print(Land.Name);

  // bei der Einwohnerzahl . durch , ersetzen
  String Einwohner =  String(Land.Einwohner);
  Einwohner.replace(".", ",");
  lcd.setCursor(0, 1);

  lcd.print(Einwohner + " Millionen");
  lcd.setCursor(0, 2);

  lcd.print("Fl\341che " + String(Land.Groesse) + " qkm");
  lcd.setCursor(0, 3);

  lcd.print("Hauptstadt " );
  lcd.print(Land.Hauptstadt);
  lcd.setCursor(0, 0);
}

Ver­wand­te Anleitungen:

Verwandte Anleitungen: