Tür­öff­ner mit einem RFID-Modul und Servomotor

Wird die kor­rek­te Kar­te an das RFID-Modul gehal­ten, öff­net der Ser­vo­mo­tor die Schran­ke, ande­ren­falls bleibt die Schran­ke geschlos­sen. Wenn die Kar­te erneut vor das Lese­ge­rät gehal­ten wird, schließt die Schran­ke wieder.

So sieht es aus:

Ein RFID-Modul (radio-frequency iden­ti­fi­ca­ti­on) besteht aus soge­nann­ten „Tags“, und einem Lesegerät.

Benö­tig­te Bauteile:

• Ser­vo­mo­tor
• RFID-Modul
• Lei­tungs­dräh­te
• kodier­te Karten

Baue die Schal­tung auf.
(Fah­re mit der Maus über das Bild, um die Bezeich­nun­gen der Bau­tei­le zu sehen)

Benö­tig­te Bibliotheken:

Ardui­no IDE 1.8x:

Sketch → Biblio­thek ein­bin­den → Biblio­the­ken verwalten

Ardui­no IDE 2.x:

Zunächst musst du die indi­vi­du­el­le Ken­nung der Kar­te herausfinden:

// RFID-Bibiothek hinzufügen
# include <MFRC522.h>

// Anschlüsse definieren
# define SDA 10
# define RST 9

// RFID-Empfänger benennen
MFRC522 mfrc522(SDA, RST);

void setup()
{
  Serial.begin(9600);
  SPI.begin();

  // Initialisierung des RFID-Empfängers
  mfrc522.PCD_Init();
}

void loop()
{
  String WertHEX;
  String WertDEZ;

  // Wenn keine Karte in Reichweite ist ..
  if (!mfrc522.PICC_IsNewCardPresent())
  {
    // .. wird die Abfrage wiederholt.
    return;
  }

  // Wenn kein RFID-Sender ausgewählt wurde ..
  if (!mfrc522.PICC_ReadCardSerial())
  {
    // .. wird die Abfrage wiederholt.
    return;
  }

  Serial.println(F("Karte entdeckt!"));

  // HEX-Werte/Dezimal-Werte in Strings schreiben
  for (byte i = 0; i < mfrc522.uid.size; i++)
  {
    WertHEX = WertHEX + String(mfrc522.uid.uidByte[i], HEX) + " ";
    WertDEZ = WertDEZ + String(mfrc522.uid.uidByte[i], DEC) + " ";

    // HEX-Werte in Großbuchstaben umwandeln
    WertHEX.toUpperCase();
  }

  // hexadezimal/dezimal anzeigen
  Serial.println("Wert in hexadezimal: " + WertHEX);
  Serial.println("Wert in dezimal: " + WertDEZ);

  delay(1000);
}

Bin­de die Biblio­the­ken ein und defi­nie­re die Variablen:

// eingebaute Bibliothek einbinden
# include <Servo.h>

// RFID-Bibiothek hinzufügen
# include <MFRC522.h>

// Anschlüsse definieren
# define SDA 10
# define RST 9

// Schranke nach Betreten wieder schließen
bool Status = false;

// RFID-Empfänger benennen
MFRC522 mfrc522(SDA, RST);

// Bezeichnung des Motors
Servo Motor;

Der setup-Teil. Beach­te die Kommentare:

void setup()
{
  // Pin des Motors zuordnen
  Motor.attach(7);
  Serial.begin(9600);

  SPI.begin();

  // Initialisierung des RFID-Empfängers
  mfrc522.PCD_Init();

  // Motor in "geschlossen"-Position fahren
  Motor.write(0);
}

Der loop-Teil. Beach­te die Kommentare.

void loop()
{
  String WertHEX;
  String WertDEZ;

  // Wenn keine Karte in Reichweite ist ..
  if (!mfrc522.PICC_IsNewCardPresent())
  {
    // .. wird die Abfrage wiederholt.
    return;
  }
  // Wenn kein RFID-Sender ausgewählt wurde ..
  if (!mfrc522.PICC_ReadCardSerial())
  {
    // .. wird die Abfrage wiederholt.
    return;
  }

  Serial.println(F("Karte entdeckt!"));

  // HEX-Werte/Dezimal-Werte in Strings schreiben
  for (byte i = 0; i < mfrc522.uid.size; i++)
  {
    WertHEX = WertHEX + String(mfrc522.uid.uidByte[i], HEX) + " ";
    WertDEZ = WertDEZ + String(mfrc522.uid.uidByte[i], DEC) + " ";

    // Kleinbuchstaben des HEX-Wertes in Großbuchstaben umwandeln
    WertHEX.toUpperCase();
  }

  Serial.println();

  // hexadezimal/dezimal anzeigen
  Serial.println("Wert in hexadezimal: " + WertHEX);
  Serial.println("Wert in dezimal: " + WertDEZ);

  // Leerzeichen am Ende entfernen
  WertDEZ.trim();

  // WertDEZ mit korrektem Wert vergleichen -> Schranke öffnen
  if (WertDEZ.compareTo("80 236 29 59") == 0)
  {
    Serial.println("korrekte Karte -> Schranke \u00f6ffnen");
    Motor.write(90);
    Status = !Status;
  }

  if (WertDEZ.compareTo("80 236 29 59") == 0 && !Status)
  {
    Serial.println("  korrekte Karte/Zutritt erfolgt -> Schranke schlie\u00dfen");
    Motor.write(5);
  }
  // wenn die Karte falsch ist
  else if (WertDEZ.compareTo("80 236 29 59") != 0)
  {
    Motor.write(5);
    Serial.println("falsche Karte -> Schranke geschlossen lassen");
    Status = false;
  }

  delay(1000);
}

Aus­ga­be im Seri­el­len Monitor

Ver­wand­te Aufgaben:

• Auto­ma­ti­sche Tür mit Hall-Sensoren
• Glücks­rad mit Schrittmotor
• Glücks­rad mit Servomotor
• Ser­vo­mo­tor mit einem Poten­tio­me­ter steuern
• Tür­öff­ner mit einem RFID-Modul und Servomotor
• Wahr­sa­ge­rin

Letzte Aktualisierung: 1. Aug 2022 @ 9:17