Labyrinth-Spiel mit TFT und Fernbedienung

Lese­zeit: 9 Minu­ten
Lösung
Seite als PDF
Navi­ga­ti­on




Mit Hil­fe einer Fern­be­die­nung wird auf einem TFT-Monitor ein Ball durch ein klei­nes Laby­rinth bewegt. Beim Druck auf die *-Tas­te wird die Zeit­mes­sung gestartet 

So sieht es aus:

Benö­tig­te Bauteile:

  • Keyes Fern­be­die­nung
  • Infra­rotem­pfän­ger
  • Adaf­ruit 1,8 Zoll TFT ST7735
  • Lei­tungs­dräh­te

Baue die Schal­tung auf:

1 -> Gnd -> GND
2 -> VCC -> 5V
3 -> RESET -> D9
4 -> D/C -> D8
5 -> CARD_CS (nicht ange­schlos­sen)
6 -> TFT_CS -> D10
7 -> MOSI -> D11
8 -> SCK -> D13
9 -> MISO (nicht ange­schlos­sen)
10 -> LITE ->5V

Pin­be­le­gung Adaf­ruit 1,8 Zoll TFT ST7735

Ach­te auf die Pin­be­le­gung des Infrarotempfängers.

Ach­te dar­auf, dass die Bat­te­rie rich­tig ein­ge­legt wur­de. Der Minus-Pol liegt oben.

Die Anlei­tung bezieht sich auf die Ver­si­on 3.x der Biblio­thek IRre­mo­te.

🔗 Anpas­sung von der Ver­si­on 2.7x zu 3.x (exter­ner Link, abge­ru­fen am 5.6.2022)

🔗 Umwand­lung von Zah­len­sys­tem (exter­ner Link, abge­ru­fen am 5.6.2022)

Die Fern­be­die­nung sen­det beim Druck auf die Tas­ten einen Zahlencode.

Die Tas­ten­codes bezie­hen sich auf die Keyes-Fernbedienung.

Tas­ten­codes Keyes-Fernbedienung (hexa­de­zi­mal und dezimal)

obenlinksrechtsuntenOK1234
0×46
70
0×44
68
0×43
67
0×15
21
0×40
64
0×16
22
0×19
25
0xD
13
0xC
12
56789+0#
0×18
24
0x5E
94
0×8
8
0x1C
28
0x5A
90
0×42
66
0×52
82
0x4A
74

Die Tas­ten­codes kannst du mit fol­gen­dem Pro­gramm her­aus­fin­den. Sie wer­den im Seri­el­len Moni­tor angezeigt. 

# include <IRremote.h>

int EmpfaengerPin = 6;

void setup()
{
  Serial.begin(9600);

  // auf serielle Verbindung warten
  while (!Serial) {;}

  // Empfänger starten
  IrReceiver.begin(EmpfaengerPin);
}

void loop()
{
  // Daten lesen
  if (IrReceiver.decode())
  {
    /*
      printIRResultMinimal zeigt die verwendete Taste
      P = Protokoll
      C = Kommando in Hex
    */

    Serial.print(F("P = Protokoll C = Taste hexadezimal: "));
    IrReceiver.printIRResultMinimal(&Serial);
    Serial.print(F(" Dezimal: "));
    Serial.println(IrReceiver.decodedIRData.command);

    delay(200);

    // nächsten Wert lesen
    IrReceiver.resume();
  }
}

Die rot umran­de­ten Wer­te wer­den von der Keyes-Fernbedienung aus­ge­ge­ben, die blau umran­de­ten stam­men von einer TV-Fernbedienung. 

Benö­tig­te Biblio­theken:

Ardui­no IDE 1.8x:

Sketch → Biblio­thek ein­bin­den → Biblio­the­ken verwalten

Ardui­no IDE 2.x:

Metho­den der Biblio­thek Adaf­ruit ST7735/TFT

Metho­deAnwei­sungPara­me­ter
TFT star­tenbegin();
Farb­sche­ma bestimmeninitR(initR(INITR_*TAB););BLACKTAB
GREENTAB
REDTAB
Bild­schirm ausrichtensetRotation(Richtung);Rich­tung = 0 → nicht drehen
Rich­tung = 1 → 90° drehen
Rich­tung = 2 → 180° drehen
Rich­tung = 3 → 270 ° drehen
Bild­schirm­hin­ter­grundfillScreen(Farbe);Bild­schirm­hin­ter­grund füllen
Linie zeich­nendrawLine(StartX, Star­tY, EndeX, EndeY, Farbe);
hori­zon­ta­le Linie zeichnendrawFastHLine(StartX, Star­tY, Län­ge, Farbe);
ver­ti­ka­le Linie zeichnendrawFastVLine(StartX, Star­tY, Län­ge, Farbe);
Recht­eck zeichnendrawRect(StartX, Star­tY,, Brei­te, Höhe, Farbe);
abge­run­de­tes Recht­eck zeichnendrawRoundRect(StartX, Star­tY, Brei­te, Höhe, Ecken­ra­di­us, Farbe);
aus­ge­füll­tes Recht­eck zeichnenfill.Rect(StartX, Star­tY, Brei­te, Höhe, Füllfarbe);
Kreis zeich­nendrawCircle(MittelpunkX, Mit­tel­punk­tY, Radi­us, Farbe);
Aus­ge­füll­ten Kreis zeichnenfillCircle(MittelpunktX, Mit­tel­punk­tY, Radi­us, Füllfarbe);
Cur­sor setzensetCursor(x, y);
Text­grö­ße setzensetTextSize(Textgröße);Text­grö­ße:
1 - 4
Text­far­be bestimmensetTextColor(Farbe);
Text schrei­benprint("Text"); println("Text");
Zei­len­um­bruchsetTextWrap(true/false);fal­se → Text fließt über den Rand des TFTs hinaus
true → Text wird am Ende umgebrochen

Bei­spiel mit Gra­fik und Text

So sieht es aus:

Adres­sie­rung der Bildpunkte

Bin­de die benö­ti­gen Biblio­the­ken ein und defi­nie­re die Varia­blen. Beach­te die Kommentare.

/*
  Pinbelegung:
  GND      (1) - GND
  VCC      (2) - 5V
  RESET    (3) - D9
  D/C      (4) - D8
  CARD-CS  (5) -
  TFT-CS   (6) - D10
  MOSI     (7) - D11
  SCK      (8) - D13
  MISO     (9) -
  LITE    (10) - 5V
*/

# include <IRremote.h>
int EmpfaengerPin = 6;

# include <Adafruit_GFX.h>
# include <Adafruit_ST7735.h>
# include <SPI.h>

// Pins definieren
# define TFT_CS        10
# define TFT_RST        9
# define TFT_DC         8

Adafruit_ST7735 tft = Adafruit_ST7735(TFT_CS, TFT_DC, TFT_RST);
/*
  Farben als hexadezimal definiert
  alternativ:
  int SCHWARZ = 0;
  int BLAU = 15;
  . . .
*/
// Farben
# define SCHWARZ    0x0000 // dezimal 0
# define BLAU       0x000F // dezimal 15
# define ROT        0xF800 // dezimal 406664
# define GRUEN      0x0E81 // dezimal 3713
# define CYAN       0x07FF // dezimal 2047
# define MAGENTA    0xF81F // dezimal 63519
# define GELB       0xAFE5 // dezimal 65504
# define WEISS      0xFFFF // dezimal 65535
# define BRAUN      0xFC00 // dezimal 64512
# define GRAU       0xF7F0 // dezimal 63472
# define GRUENGELB  0xAFE5 // dezimal 45029
# define DUNKELCYAN 0x03EF // dezimal 1007
# define ORANGE     0xFD20 // dezimal 64800
# define PINK       0xFC18 // dezimal 64536

// Farbe der Blöcke
# define FARBE GRUEN

// Farbe des Kreises
# define KREISFARBE GELB

// Farbe der Schrift
# define SCHRIFTFARBE WEISS

// Spiel starten wenn * gedrückt wurde
bool SpielStart = false;

// Radius des kreises
const int Radius = 10;

// Abstand zu den Rändern
const int Abstand = Radius * 2;

// je höher, dest langsamer
const int Geschwindigkeit = 100;

// Bewegung des Kreises in Pixeln
const int Bewegung = 5;

// Startposition des Kreises
int CursorX = Radius;
int CursorY = tft.height() / 2 - Abstand;

// Variable für die Zeitmessung
long Start;

Der setup-Teil:

void setup()
{
  // Startbildschirm
  // schwarzes Farbschema vertkale Ausrichtung (nicht drehen)
  // Cursor setzen, Schriftgröße und -farbe definieren
  tft.initR(INITR_BLACKTAB);
  tft.setRotation(0);
  tft.fillScreen(SCHWARZ);
  tft.setTextSize(2);
  tft.setCursor(1, 10);
  tft.setTextColor(ROT);

  tft.println("Start:");
  tft.print("-> *");
  IrReceiver.begin(EmpfaengerPin);
}

Der loop-Teil. Beach­te die Kommentare.

void loop()
{
  if (IrReceiver.decode())
  {
    delay(100);

    // nächsten Wert lesen
    IrReceiver.resume();

    // Start mit *
    if (IrReceiver.decodedIRData.command == 0x42)
    {
      // Spiel wird gestartet
      SpielStart = true;

      // Parcours bauen
      ParcoursBauen();

      // Zeitmessung starten
      Start = millis();
    }
  }

  // wenn der Button * gedrückt wurde
  if (SpielStart)
  {

    // Taste OK
    if (IrReceiver.decodedIRData.command == 0x40)
    {
      // Kreis an der aktuellen Position anhalten
      tft.fillCircle(CursorX, CursorY, Radius, KREISFARBE);
    }

    // Taste nach oben
    if (IrReceiver.decodedIRData.command == 0x46)
    {
      // Kreis an der aktuellen Position "löschen"
      tft.fillCircle(CursorX, CursorY, Radius, SCHWARZ);

      // wenn der Bildschirmrand oben noch nicht erreicht wurde
      // rückwärts -> Richtung x = 1 bewegen
      if (CursorY > Radius) CursorY -= Bewegung;

      // Kreis an der neuen Position zeichnen
      tft.fillCircle(CursorX, CursorY, Radius, KREISFARBE);
      delay(Geschwindigkeit);
    }

    // Taste nach unten
    if (IrReceiver.decodedIRData.command == 0x15)
    {
      // Kreis an der aktuellen Position "löschen"
      tft.fillCircle(CursorX, CursorY, Radius, SCHWARZ);

      // wenn der Bildschirmrand rechts noch nicht erreicht wurde
      // vorwärts -> Richtung tft.height() bewegen
      if (CursorY < tft.height() - Radius) CursorY += Bewegung;

      // Kreis an der neuen Position zeichnen
      tft.fillCircle(CursorX, CursorY, Radius, KREISFARBE);
      delay(Geschwindigkeit);
    }

    // Taste nach links
    if (IrReceiver.decodedIRData.command == 0x44)
    {
      // Kreis an der aktuellen Position "löschen"
      tft.fillCircle(CursorX, CursorY, Radius, SCHWARZ);

      // wenn der Bildschirmrand links noch nicht erreicht wurde
      // rückwärts -> Richtung linken Bildschirmrand bewegen
      if (CursorX > Radius) CursorX -= Bewegung;

      // Kreis an der neuen Position zeichnen
      tft.fillCircle(CursorX, CursorY, Radius, KREISFARBE);
      delay(Geschwindigkeit);
    }

    // Taste nach rechts
    if (IrReceiver.decodedIRData.command == 0x43)
    {
      // Kreis an der aktuellen Position "löschen"
      tft.fillCircle(CursorX, CursorY, Radius, SCHWARZ);

      // Abfrage, ob der rechte Rand erreicht wurde, nicht nötig
      // wird in der nächsten bedingung abgefragt
      CursorX += Bewegung;

      // Kreis an der neuen Position zeichnen
      tft.fillCircle(CursorX, CursorY, Radius, KREISFARBE);
      delay(Geschwindigkeit);
    }

    // rechter Bildschirmrand erreicht -> Spielende
    if (CursorX > tft.height() - Radius)
    {
      ErgebnisZeigen();
    }
  }
}

Jetzt feh­len noch die Metho­den Ergeb­nis­Zei­gen() und ParcoursBauen():

void ErgebnisZeigen()
{
  // Zeit berechnen
  int Sekunden;
  long VerstricheneZeit = millis() - Start;
  Sekunden = int(VerstricheneZeit / 1000);

  // Zeit anzeigen
  tft.fillScreen(SCHWARZ);
  tft.setTextSize(2);
  tft.setCursor(1, 10);
  tft.println("Zeit:");
  tft.println(String(Sekunden) + " s");

  tft.setCursor(1, 40);
  tft.setTextColor(ROT);
  tft.println();
  tft.println("Neustart:");
  tft.println("-> *");
  SpielStart = false;
}

void ParcoursBauen()
{
  CursorX = Radius;
  CursorY = tft.height() / 2 - Abstand;
  tft.fillScreen(SCHWARZ);

  // Kreis anzeigen
  tft.fillCircle(CursorX, CursorY, Radius, KREISFARBE);

  // Parcours "bauen"
  tft.fillRect(65, 35, 5, 45, FARBE);
  tft.fillRect(1, 1, 35, 35, FARBE);
  tft.fillRect(1, 80, 70, 80, FARBE);
  tft.fillRect(110, 1, 70, 95, FARBE);
  tft.fillRect(110, 130, 140, 160, FARBE);
}

Startseite
Aufgaben A-Z
Suchen
Downloads
Fehlermeldungen
Seite als PDF

Ver­wand­te Aufgaben:


Letzte Aktualisierung: 4. Jun 2022 @ 10:05