Pin-Eingabe

Auf einem Tas­ten­feld soll ein Pin ein­ge­ge­ben wer­den. Das Pro­gramm soll die­sen Pin („1234“) abfra­gen. Wur­de der Pin nach Druck auf die Tas­te # rich­tig ein­ge­ge­ben, wird die Mel­dung „kor­rek­ter Pin“ angezeigt.

Pin­ein­ga­be Seri­el­ler Monitor

Bei die­ser Auf­ga­be lernst du ver­schie­de­ne Mög­lich­kei­ten ken­nen einen String auszuwerten:

• BeispielString.indexOf(Zeichen) → bestimmt die Posi­ti­on eines Zei­chens inner­halb des Strings
• BeispielString.length() → ermit­telt die Län­ge eines Strings
• BeispielString.substring(Start, Ende) → zeigt den Teil des Strings von Start bis Ende

Bei­spiel:

Der String "Pro­gram­mie­ren fin­de ich toll ;-)" soll auf sei­ne Län­ge und die Pos­ti­on des „t“ unter­sucht wer­den. Anschlie­ßend wird er in zwei Teil­strings zerlegt.

void setup()  
{
  Serial.begin(9600);  
  String BeispielString = "Programmieren finde ich toll ;-)"; 

  // Länge bestimmen 
  int Laenge = BeispielString.length();  
  Serial.print("Laenge des Strings: "); 
  Serial.println(Laenge); 

  // das t suchen 
  int Suche = BeispielString.indexOf("t");     
  Serial.print("Position t: "); 
  Serial.println(Suche); 
 
  // String vom Anfang bis zum t  
  BeispielString.substring(0, Suche); 
  Serial.print("String bis zum t: ");      
  Serial.println(BeispielString.substring(0, Suche));

  // oder, weil Laenge schon bestimmt wurde: 
  // BeispielString.substring(suche + 1, Laenge);    

  Serial.print("String vom t bis zum Ende: ");     
  Serial.println(BeispielString.substring(Suche, BeispielString.length())); 
} 

void loop()  
{ 
  // bleibt leer → das Programm soll nur einmal ausgeführt werden 
}

➨Wei­te­re Informationen

Benö­tig­te Bauteile:

• Laut­spre­cher
• Tas­ten­feld 3×4
• Lei­tungs­dräh­te

Baue die Schal­tung auf:
(Fah­re mit der Maus über das Bild, um die Bezeich­nun­gen der Bau­tei­le zu sehen)

Es sind eini­ge Schrit­te zur Vor­be­rei­tung nötig. Im Kopf des Pro­gramms müs­sen ver­schie­de­ne Varia­ble defi­niert werden:

Du benö­tigst die Biblio­thek Keypad:

Sketch → Biblio­thek ein­bin­den → Biblio­the­ken verwalten

Das Tas­ten­feld besteht aus Rei­hen und Spal­ten, die von unten nach oben in einem ➨zwei­di­men­sio­na­len Array ange­ord­net werden:

Bin­de die Biblio­thek ein und defi­nie­re die Variablen:

# include <Keypad.h>
String Eingabe;
int LAUTSPRECHER = 13;

// Größe des Tastenfeldes
// 3 Spalten
const byte SPALTEN = 3;

// 4 Zeilen
const byte REIHEN = 4;

// die Ziffern/Zeichen:
// Array 3 x 4
char Tasten[REIHEN][SPALTEN] = {
  {'#', '0', '*'},
  {'9', '8', '7'},
  {'6', '5', '4'},
  {'3', '2', '1'}
};

// die Pins für die 3 Spalten
byte SpaltenPins[SPALTEN] = { 2, 3, 4 };

// die Pins für die 4 Zeilen
byte ReihenPins[REIHEN] = { 8, 9, 10, 11 };

// TastenFeld → Name des Keypads
// → Zuordnung der Pins zu den REIHEN und SPALTEN des Arrays
Keypad TastenFeld = Keypad(makeKeymap(Tasten), ReihenPins, SpaltenPins, REIHEN, SPALTEN);

char gedrueckteTaste;
String Vergleich;
String Pin = "1234";

Jetzt kann die eigent­li­che Pro­gram­mie­rung begin­nen.
Der setup-Teil:

void setup() 
{
  pinMode(LAUTSPRECHER, OUTPUT);
  Serial.begin(9600);

  delay(500);

  // nur beim Start anzeigen
  Serial.println("Pin-Eingabe");
  Serial.println("mit # abschließen");
  Serial.println("Korrektur mit * ");
  Serial.println("---------------------");
}

Der loop-Teil. Beach­te die Kommentare.

void loop()  
{ 
  // gedrückte Taste abfragen 
  gedrueckteTaste = TastenFeld.getKey(); 
  // wenn eine Taste gedrückt wurde
  if (gedrueckteTaste)  
  { 
    tone(LAUTSPRECHER, 1000); 
    delay(50); 
    noTone(LAUTSPRECHER); 

    // # soll nicht angezeigt werden  
    if (gedrueckteTaste != '#') Serial.print(gedrueckteTaste);          
    Eingabe = Eingabe + gedrueckteTaste;  

    // Korrektur mit *  
    if (gedrueckteTaste == '*' && Eingabe.length() > 1) 
    {     
      // letztes Zeichen ist * -> muss entfernt werden        
      Eingabe = Eingabe.substring(0, Eingabe.length() - 2);  
      Serial.println("Korrektur: ");  
      Serial.print(Eingabe); 
    } 

    if (gedrueckteTaste == '#') 
    {   
      // letztes Zeichen ist # -> muss entfernt werden       
      String Vergleich = Eingabe.substring(0, Eingabe.length() - 1);   
      if (Vergleich == Pin)  
      {   
        Serial.println("\tPin ist korrekt - Zugriff");  
      }       
      else Serial.println("\tFalscher Pin - kein Zugriff");       
      Eingabe = "";  
    } 
  } 
}  

Ver­wand­te Aufgaben:

• Far­ben­spie­le mit einem LED-Streifen
• Far­ben­spie­le mit einer RGB-LED
• Länder-Info
• LEDs mit einem Tas­ten­pad schalten
• Multiplikations-Taschenrechner
• Spiel­uhr mit dem Tastenpad
• Töne erzeu­gen mit dem Tastenfeld

Letzte Aktualisierung: 11. Apr 2021 @ 10:01